Rewrap/flake.nix at master · dnut/Rewrap · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "Development shell for Rewrap Revived";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";

  outputs =
    { nixpkgs, ... }:
    let
      forAllSystems =
        f:
        nixpkgs.lib.genAttrs
          [
            "x86_64-linux"
            "aarch64-linux"
            "x86_64-darwin"
            "aarch64-darwin"
          ]
          (
            system:
            let
              pkgs = import nixpkgs {
                inherit system;
                # VS Code is used to run the vscode tests
                config.allowUnfreePredicate = pkg: nixpkgs.lib.getName pkg == "vscode";
              };
            in
            f pkgs
          );
    in
    {
      formatter = forAllSystems (pkgs: pkgs.nixfmt);
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs; [
            dotnet-sdk_10
            nodejs_26
            (python3.withPackages (
              ps: with ps; [
                mkdocs
                mkdocs-material
                pymdown-extensions
              ]
            ))
            vsce
            xvfb-run
          ];

          VSCODE_TEST_EXECUTABLE =
            if pkgs.stdenv.isDarwin then
              "${pkgs.vscode}/Applications/${pkgs.vscode.longName}.app/Contents/MacOS/Code"
            else
              "${pkgs.vscode}/lib/vscode/code";

          shellHook = ''
            cat <<EOF

            Rewrap Revived Dev Shell

                dotnet $(dotnet --version)
                node   $(node --version)
                npm    $(npm --version)
                python $(python3 --version | awk '{print $2}')
                mkdocs $(mkdocs --version | awk '{print $3}')
                vsce   $(vsce --version)
                xvfb   ${pkgs.xorg-server.version}

            EOF
          '';
        };
      });
    };
}